source: SH_SHM/trunk/setup/SHM-install.csh @ 345

Revision 345, 8.1 KB checked in by marcus, 8 years ago (diff)

r184 | walther | 2011-03-10 15:52:38 +0100 (Do, 10 Mär 2011) | 1 line

Updated list of graphical text editors.

  • Property svn:executable set to *
Line 
1#! /bin/csh
2#
3# file install.csh
4#      ===========
5#
6# version 5, 17-Feb-2011
7#
8# Installation script for SH/SHM package
9
10set ext="undefined"
11if  ("`uname`" == "Linux")  then
12        set ext="linux"
13else if  ("`uname`" == "SunOS")  then
14        set ext="sol2.5.1"
15endif
16
17if  ("$1" == "")  then
18        echo "To be only used from self-extracting setup process!"
19else
20        # get parameters
21        set dstpath=$1
22endif
23
24# check parameters
25if  (! -w $dstpath)  then
26        echo "$0 : cannot write to installation path $dstpath.  Abort."
27        exit 1
28endif
29
30# find input files
31set pack_fk=""
32set pack_locsat=""
33
34if  ("`uname`" == "Linux")  then
35        if  (-e $dstpath/fk-linux.tar.gz)  set pack_fk=$dstpath/fk-linux.tar.gz
36        if  (-e $dstpath/locsat-linux.tar.gz)  set pack_locsat=$dstpath/locsat-linux.tar.gz
37else if  ("`uname`" == "SunOS")  then
38        if  (-e $dstpath/fk-sol2.5.1.tar.gz)  set pack_fk=$dstpath/fk-sol2.5.1.tar.gz
39        if  (-e $dstpath/locsat-sol2.5.1.tar.gz)  set pack_locsat=$dstpath/locsat-sol2.5.1.tar.gz
40else
41endif
42
43if  (-e $dstpath/libahio.a.$ext)  then
44        set use_ah=1
45else
46        set use_ah=0
47endif
48
49
50# default values
51set displ_res="undef"
52set userroot='$HOME/shfiles'
53if  ("`uname`" == "Linux")  then
54        set linux_colors="yes"
55else
56        set linux_colors="no"
57endif
58
59# find text editor
60set editor=""
61foreach  ed  (kwrite gedit textedit nedit vuepad xedit leafedit mousepad)
62        set res=`which $ed`
63        if  (-e "$res")  then
64                set editor=$ed
65                break
66        endif
67end
68
69# check for some programs in search path
70set plist = ( gzip make makedepend gcc uil ar ranlib xterm )
71foreach p ($plist)
72        set res=`which $p`
73        if  (! -e "$res")  then
74                echo "Program $p not found in search path.  Please add."
75                exit 2
76        endif
77end
78
79# enter setup menu
80
81set cmd=""
82while  ("$cmd" != "i")
83
84        echo "======================================================================"
85        echo ""
86        echo "(u)  user root path:           $userroot"
87        echo "(e)  window based texteditor:  $editor"
88        echo "(c)  linux colors:             $linux_colors"
89        echo "(i)  Start Installation"
90        echo "(q)  Quit Installation"
91        echo ""
92        echo "If all settings are ok, enter 'i'"
93        echo ""
94        echo -n "Your command: "
95        set cmd="$<"
96
97        if  ("$cmd" == "q")  exit 99
98        if  ("$cmd" == "r")  then
99                if  ("$displ_res" == "xga")  then
100                        set displ_res="wxga"
101                else if  ("$displ_res" == "wxga")  then
102                        set displ_res="sxga"
103                else
104                        set displ_res="xga"
105                endif
106        endif
107        if  ("$cmd" == "c")  then
108                if  ("$linux_colors" == "yes")  then
109                        set linux_colors="no"
110                else
111                        set linux_colors="yes"
112                endif
113        endif
114        if  ("$cmd" == "e")  then
115                echo -n "window based texteditor: "
116                set editor="$<"
117                if  (! -e $editor)  then
118                        echo "$editor does not exist."
119                        echo -n "Enter <Return> ..."
120                        set x="$<"
121                        set editor=""
122                endif
123        endif
124        if  ("$cmd" == "u")  then
125                echo -n "user root path: "
126                set userroot="$<"
127                if  (! -e $userroot)  then
128                        mkdir $userroot
129                        if  (! -e $userroot)  then
130                                echo "cannot create $userroot. Reset to default."
131                                echo -n "Enter <Return> ..."
132                                set x="$<"
133                                set userroot=$HOME/shfiles
134                        endif
135                endif
136        endif
137        if  ("$cmd" == "i")  then
138                if  ("$editor" == "")   then
139                        echo "Please specify window based texteditor executable."
140                        echo -n "Enter <Return> ..."
141                        set x="$<"
142                        set cmd="."
143                endif
144        endif
145end
146
147cd $dstpath
148
149# create setup file from template
150echo "prepare setup file"
151cd sh/setup
152if  ("`uname`" == "Linux")  then
153        set remstr="#OS-linux "
154else if  ("`uname`" == "SunOS")  then
155        set remstr="#OS-sol2 "
156else
157        echo "$0 : sorry, this operating system is not supported"
158        exit 3
159endif
160set locsatpath=$dstpath/sh/util/locsat
161set plth=`echo $locsatpath | wc -c`
162if  ($plth > 25)  then
163        if  (-e $HOME/lcs)  \rm $HOME/lcs
164        ln -s $locsatpath $HOME/lcs
165        set locsatpath=$HOME/lcs
166        set plth=`echo $locsatpath | wc -c`
167        if  ($plth > 25)  then
168                echo "$0 : cannot find short locsat path.  Abort."
169                exit 4
170        endif
171endif
172if  (-e shsetup)  \rm shsetup
173sed "s/$remstr//" shsetup.template | sed "s@##ROOTPATH##@$dstpath/sh@" | \
174        sed "s@##LOCSATPATH##@$locsatpath@" | sed "s@##EDITOR##@$editor@" | \
175        sed 's/-DSH_SETUP_SZGRF//' | sed "s@##USERROOT##@$userroot@" >shsetup
176sed "s/$remstr//" shsetup.sh.template | sed "s@##ROOTPATH##@$dstpath/sh@" | \
177        sed "s@##LOCSATPATH##@$locsatpath@" | sed "s@##EDITOR##@$editor@" | \
178        sed 's/-DSH_SETUP_SZGRF//' | sed "s@##USERROOT##@$userroot@" >shsetup.sh
179
180if  ($use_ah == 0)  then
181        sed --in-place 's/-DSH_SETUP_AH//' shsetup
182        sed --in-place 's/-lahio//' shsetup
183endif
184if  ($?MACHTYPE == 1)  then
185        if  ("`echo $MACHTYPE | grep 64`" != "")  then
186                if  (-d /usr/X11R6/lib64)  then
187                        sed --in-place 's/\/usr\/X11R6\/lib/\/usr\/X11R6\/lib64/' shsetup
188                        sed --in-place 's/\/usr\/X11R6\/lib/\/usr\/X11R6\/lib64/' shsetup.sh
189                endif
190        endif
191endif
192source shsetup
193
194# create directories for evt files
195if (! -e $SH_USERROOT/evt/evid ) mkdir -p $SH_USERROOT/evt/evid
196if (! -e $SH_USERROOT/evt/evtout ) mkdir -p $SH_USERROOT/evt/evtout
197
198# find screen resolution
199set displ_res=`$dstpath/sh/util/get_screen_resolution.csh`
200if  ($#displ_res != 3)  then
201        echo "cannot find screen resolution, please set manually"
202        set displ_res="sxga"
203else
204        echo "found screen resolution $displ_res"
205        set displ_res=$displ_res[3]
206endif
207
208set origsetup=$dstpath/sh/inputs/shm-config-default.txt
209if  (! -e $origsetup)  then
210        echo "Installation program error.  Sorry."
211        exit  5
212endif
213set thissetup=$dstpath/sh/inputs/shm-config.txt
214if  (-e $thissetup)  then
215    \mv $thissetup $dstpath/sh/inputs/shm-config.txt.yours
216    echo "A backup of your shm-config.txt has been saved under:"
217    echo $dstpath/sh/inputs/shm-config.txt.yours
218endif
219sed "s@##EDITOR##@$editor@" $origsetup > $thissetup
220
221# settings for small displays (laptops)
222if  ("$displ_res" != "" && "$displ_res" != "sxga")  then
223        sed --in-place "s/shm-cof-sxga-geometry/shm-conf-$displ_res-geometry/" $thissetup
224endif
225
226# linux colors
227if  ("$linux_colors" == "yes")  then
228        # do nothing, this is default
229else
230        sed --in-place 's/reverse_xors                 true/reverse_xors                 false/' $thissetup
231endif
232
233echo "compiling SHM"
234cd $SH_ROOT
235# remove all o's and a's
236find . -name '*.o' -print0 | xargs -0 rm
237cd $SH_LIB
238if  (-e libahio.a)  mv libahio.a libahio.ax
239\rm *.a > /dev/null
240if  (-e libahio.ax)  mv libahio.ax libahio.a
241cd $SH_ROOT
242make depend_shm
243make shm
244make world
245
246# install FK
247echo "extract FK package"
248cd $SH_UTIL
249if  (-e fk_src)  \rm -rf fk_src
250cp $pack_fk .
251set pack_fk=$pack_fk:t
252gzip -d $pack_fk
253set pack_fk=$pack_fk:r
254chmod +w $pack_fk
255tar xf $pack_fk
256\rm $pack_fk
257if  (-e fk)  \rm fk
258ln -s fk_src/fk fk
259
260# install LocSAT
261echo "extract LocSAT package"
262cd $SH_UTIL
263if  (-e locsat)  \rm -rf locsat
264mkdir locsat
265cp $pack_locsat .
266set pack_locsat=$pack_locsat:t
267gzip -d $pack_locsat
268set pack_locsat=$pack_locsat:r
269chmod +w $pack_locsat
270tar xf $pack_locsat
271\rm $pack_locsat
272if  (-e LocSAT)  \rm LocSAT
273ln -s locsat/bin/LocSAT LocSAT
274
275# add SHM resources to .Xdefaults
276set resrc=""
277if  (-e ~/.Xdefaults)  set resrc=~/.Xdefaults
278if  ("$resrc" == "")  then
279        if  (-e ~/.Xresources)  set resrc=~/.Xresources
280endif
281if  ("$resrc" == "")  then
282        set resrc="~/.Xdefaults"
283        touch $resrc
284endif
285set res=`grep "SHM.locsat_prefix_text" $resrc`
286if  ("$res" == "")  then
287        echo "SHM*locsat_prefix_text.value:       tab"  >>$resrc
288        echo "SHM*fk_frqlo_text.value:            0.4"  >>$resrc
289        echo "SHM*fk_frqhi_text.value:            3.0"  >>$resrc
290        echo "SHM*fk_slowness_text.value:         15"   >>$resrc
291        echo "SHM*fk_resol_text.value:            51"   >>$resrc
292        echo "SHM*fk_colnum_text.value:           10"   >>$resrc
293        echo "SHM*filter_butpar_hi_text.value:    1Hz"  >>$resrc
294        echo "SHM*filter_butpar_lo_text.value:    100s" >>$resrc
295        echo "SHM*filter_butpar_order_text.value: 4"    >>$resrc
296        echo "SHM*opick_thresh_text.value:        10.0" >>$resrc
297        echo "SHM*opick_duration_text.value:      1.0"  >>$resrc
298        echo "SHM*opick_break_text.value:         0.00" >>$resrc
299endif
300xrdb $resrc
301
302echo "========================================================================"
303echo ""
304echo "Please update your environment before using SH or SHM!"
305echo ""
306echo "If you prefer csh or tcsh put this line into your ~/.cshrc file:"
307echo "source $dstpath/sh/setup/shsetup"
308echo ""
309echo "If you prefer bash put this line into your ~/.bashrc file:"
310echo "source $dstpath/sh/setup/shsetup.sh"
311echo ""
312echo "========================================================================"
Note: See TracBrowser for help on using the repository browser.